data={
{2006+8/12,2011+9/12},
{2010+5/12,2012+5/12},
{2012+4/12,2013+2/12},
{2012+9/12,2013+9/12},
{2013+0/12,2014+10/12},
{2014+0/12,2015+10/12},
{2014+1/12,2016+10/12},
{2014+4/12,2017+10/12},
{2014+10/12,2017+8/12},
{2017+0/12,2018+5/12},
{2017+10/12,2020+9/12},
{2018+2/12,2020+5/12},
{2019+3/12,2020+11/12}
};

Plot and simple fit

Show[{
ListStepPlot[data,AspectRatio->1,PlotRange->{{2006,2022},{2006,2022}},PlotStyle->LightGray],
ListPlot[data,PlotStyle->Black],
Plot[x,{x,2006,2022},PlotStyle->Gray]
}]

Plot and fit of >2017

fitFull=LinearModelFit[data,{x},x];
fit2017=LinearModelFit[Select[data,First[#]>2017&],{x},x];
Show[{
ListPlot[data,AspectRatio->1,PlotRange->{{2006,2022},{2006,2022}}],
Plot[{x,fitFull[x],fit2017[x]},{x,2006,2022}]
}]

Solve for opening date

Solve[fitFull[x]==x,x]
Solve[fit2017[x]==x,x]

Solve for opening date but with error propagation

a*x + b = x   -->     -(b/(a-1))

AroundReplace[b/(1-a),{{b,a}->VectorAround[fit2017["BestFitParameters"],fit2017["CovarianceMatrix"]]}]

OldFaithful

data=Reverse/@ExampleData[{"Statistics","OldFaithful"}];

Primitive fit: a*LogisticSigmoid[f*(x-t)]+c

fit=NonlinearModelFit[data,a*LogisticSigmoid[f*(x-t)]+c,{a,f,{t,70},c},x];
Show[{ListPlot[data],Plot[fit[x],{x,40,100}]},PlotTheme->"Scientific",ImageSize->Medium]

fit["ParameterTable"]

Uncertainty estimation

dataS=If[Length[#]>1,{#[[1,1]],MeanAround[#[[All,2]]]},Nothing]&/@Normal[GroupBy[data,First]][[All,2]] (*fürs plotten*)
dataSFit=If[Length[#]>1,{#[[1,1]],Mean[#[[All,2]]]},Nothing]&/@Normal[GroupBy[data,First]][[All,2]] (*für den fit*)

fitS=NonlinearModelFit[dataSFit,a*LogisticSigmoid[f*(x-t)]+c,{a,f,{t,65},c},x,Weights->(1/(dataS[[All,2,2]]^2)),VarianceEstimatorFunction->(1&)];

Show[{
ListPlot[dataS,PlotStyle->Black,IntervalMarkers->"Bars"],
Plot[fitS[x],{x,40,100},PlotStyle->Black]
}]

Why correlations matter

confBand[xVal_]:={Plus@@#,Subtract@@#}&@AroundReplace[a*LogisticSigmoid[f*(x-t)]+c,{x->Around[xVal,0.5],{a,f,t,c}->VectorAround[fitS["BestFitParameters"][[All,2]],fitS["CorrelationMatrix"]]}]
confBand2[xVal_]:={Plus@@#,Subtract@@#}&@AroundReplace[a*LogisticSigmoid[f*(x-t)]+c,(#[[1]]->Around@@#[[{2,3}]]&/@Transpose[{fitS["BestFitParameters"][[All,1]],fitS["BestFitParameters"][[All,2]],fitS["ParameterErrors"]}])~Join~{x->Around[xVal,0.5]}]
fitS=NonlinearModelFit[dataSFit,a*LogisticSigmoid[f*(x-t)]+c,{a,f,{t,65},c},x,Weights->(1/(dataS[[All,2,2]]^2)),VarianceEstimatorFunction->(1&)];
Show[{
ListPlot[data,PlotStyle->LightGray],
Plot[Evaluate[{fitS[x]}~Join~(fitS["SinglePredictionBands",ConfidenceLevel->0.683])~Join~confBand[x]~Join~confBand2[x]],{x,40,100},PlotStyle->{Black,LightGray,LightGray,Red,Red,Blue,Blue},Filling->{2->{3}}],
ListPlot[dataS,PlotStyle->Black,IntervalMarkers->"Bars"]
}]

fitS["CorrelationMatrix"]//MatrixForm